Bonjour
Les relations entre AppleScript et les règles de Mail se sont notoirement dégradées depuis plusieurs versions.
Puisque vous envisagez de sélectionner et copier le contenu je vous propose un script effectuant directement le travail.
N'utilisant pas Excel j'ai testé le fonctionnement avec Numbers.
#<Code>
tell application "Mail"
# récupère le message sélectionné
set unMessage to item 1 of (get the selection)
# garni le presse papiers avec le contenu du message
set the clipboard to (get content of unMessage)
end tell
tell application "Numbers"
set monTableur to make new document
tell monTableur to tell sheet 1 to tell table 1
# Comme la table par défaut est dotée d'une rangée d'en-tête
# et d'une colonne d'en-tête je supprime ces "parasites".
remove row 1
remove column 1
# spécifie le point où l'on collera
set selection range to range "A1"
end tell
end tell
tell application "System Events" to tell process "Numbers"
set frontmost to true
keystroke "v" using {command down} # Colle le contenu du presse-papiers
end tell
set p2d to path to documents folder as text # Adaptez à vos souhaits
set nomDuDoc to "mon tableur.numbers" # Adaptez à vos souhaits
set leChemin to p2d & nomDuDoc as «class furl»
tell application "Numbers"
save monTableur in leChemin # Enregistre le document
end tell
#</Code>
Yvan KOENIG running High Sierra 10.13.6 in French (VALLAURIS, France) lundi 14 octobre 2019 17:54:49
_______________________________________________
Applescript_fr mailing list
Applescript_fr@???
http://listes.patpro.net/mailman/listinfo/applescript_fr